Unicode Support

AppleScript is now entirely Unicode-based. Comments and text constants in scripts may contain any Unicode characters, and all text processing is done in Unicode, so all characters are preserved correctly regardless of the user’s language preferences. For example, this script works correctly in AppleScript 2.0, where it would not have in previous versions:

set jp to "日本語"

set ru to "Русский"

jp & " and " & ru -- returns "日本語 and Русский"

There is no longer a distinction between Unicode and non-Unicode text. There is exactly one text class, named “text”: that is, class of "foo" returns text. It is functionally equivalent to the former Unicode text class, so it may contain any Unicode character, and has two new features besides:

• text objects have an id property, which may also be used as an address.

  These allow mapping between Unicode code point values and the characters at those code points: for example, id of "A" returns 65, and character id 65 returns "A". The id of text longer than one code point is a list of integers, and vice versa: for example, id of "hello" returns {104, 101, 108, 108, 111}, and string id {104, 101, 108, 108, 111} returns "hello". (Because of a bug, text id ... does not work; you must use one of string, Unicode text, or character.) These obsolete the older ASCII character and ASCII number commands, since, unlike those, they cover the full Unicode character range and will return the same results regardless of the user's language preferences. [2915643]

• character elements of text count a grapheme cluster as a single character.

  Some “characters” may be composed of a series of Unicode code points, what Unicode defines as a grapheme cluster. For example, “é” may be encoded as U+0065 (LATIN SMALL LETTER E), U+0301 (COMBINING ACUTE ACCENT). AppleScript 2.0 will count the cluster as one character, where older versions counted the base character and combining mark separately. For a complete definition of grapheme clusters, see UAX #29: Unicode Text Segmentation. [4192557]

Matching of text item delimiters now respects considering and ignoring attributes, where previous versions ignored them. The expansion attribute is no longer supported.

The change to all-Unicode necessitated a change in the read and write commands and how they deal with text encodings. Formerly, they would write string objects using the primary encoding and Unicode text objects as UTF-16, unless instructed otherwise using an as parameter. Now that there is only one text class, the read and write commands rely solely on the as parameter to determine the encoding: with no as parameter, as text, or as string, they use the primary encoding; with as Unicode text, they use UTF-16. For the most reliable results when creating scripts that will run on both 2.0 and pre-2.0, always specify the encoding explicitly using as text or as Unicode text, as appropriate. [4421553]

someObject as text

someObject as string

someObject as Unicode text

Application Objects

application objects in AppleScript have some new features designed to reduce the need for awkward or obscure workarounds. In other words, the capabilities are not new, but they are now directly supported and easier to use.

• Is an application running?

  While System Events is capable of telling you whether or not an application is running, it takes several lines to do it. application objects now have a running property that can give you the answer directly, without invoking System Events. For example, the following script pauses iTunes, but will not launch it if it is not already running:

  tell application "iTunes"

  if it is running -- same thing as "if running" or "if running is true"

  pause

  end if

  end tell

  running does not need to appear inside a tell block; the above script could also be written like this:

  if application "iTunes" is running

  tell application "iTunes" to pause

  end if

• Is an application frontmost?

  application objects now have a frontmost property similar to running, including that the information is available from System Events, but it tells you whether or not the application is in front. The value of frontmost for background-only applications, UI element applications such as System Events, and applications that are not running is always false.

• Get an application’s version

  Most applications have a version property of their own, but using it requires that the application be running, and sometimes you specifically want to avoid that. The new built-in version property will return the application version as text without launching the application or sending it an event. There is also a corresponding built-in name property; the value is usable as the name of an application to tell.

• Target applications by signature or bundle identifier [3858040]

  Doing this in older versions requires a multi-line incantation using Finder. It is now possible to simply address an application object by id, where the id is either the bundle identifier or the four-character signature code. For example, application "Mail", application id "com.apple.mail", and application id "emal" all refer to Mail.app, and will all work as the target of a tell block, as in this example:

  tell application id "com.apple.mail"

  get unread count of inbox

  end tell

  There is a corresponding id property, so you can get the necessary id to tell:

  get id of application "TextEdit"

  -- returns "com.apple.TextEdit"

  -- Now we know that 'tell application id "com.apple.TextEdit"' will work.

  This does not require that the application be running.

  When running a script, if an application specified by id is not found, AppleScript will not ask where it is. It will throw an error, which can be caught using a try block.

  Scripts intended for distribution should use the id form. That way, the script will continue to work even if the user has changed the name of the application.

In addition, there are several changes to application behavior to make them easier to deal with:

• Applications launch hidden.

  AppleScript has always launched applications if it needed to in order to send them a command. However, they would always launch visibly, which could be visually disruptive. AppleScript now launches applications hidden by default. They will not be visible unless the script explicitly says otherwise using launch or activate.

• Applications are located lazily.

  When running a script, AppleScript will not attempt to locate an application until it needs to in order to send it a command. This means that a compiled script or script application may contain references to applications that do not exist on the user’s system, but AppleScript will not ask where the missing applications are until it encounters a relevant tell block. Older versions of AppleScript would attempt to locate every referenced application before running the script.

  When opening a script, AppleScript will attempt to locate all the referenced applications in the entire script, which may mean asking where one is. Pressing the Cancel button only cancels the search for that application; the script will continue opening normally, though custom terminology for that application will display as raw codes. In older versions, pressing Cancel would cancel opening the script.

• Applications are located and re-located dynamically.

  application object specifiers, including those in tell blocks, are evaluated every time the script runs. This alleviates problems with scripts getting “stuck” to a particular copy of an application. [4356296]

Scriptability and VoiceOver

AppleScript Utility and Folder Actions Setup are now scriptable, and Script Editor’s scriptability has been enhanced thanks to improvements in Cocoa Scripting. All three applications are now VoiceOver-aware.

Scriptable Network Preferences

Networking preferences are now accessible via scripting using a new suite in System Events, where they were previously only scriptable via accessibility. A script can inspect various networking settings, and can tell a service to connect or disconnect. For example, the following script locates a PPPoE service in the current location and tells it to connect if it exists.

tell application "System Events"

    tell network preferences

        tell current location

            set aPPPoEService to a reference to (first service whose kind is 10)

            if exists aPPPoEService then

                connect aPPPoEService

            end if

        end tell

    end tell

end tell

Command Line Support

AppleScript now allows # as a comment-to-end-of-line token, in addition to --. This means that you can make a plain text AppleScript script into a Unix executable by beginning it with the line #!/usr/bin/osascript and giving it execute permission. For details of osascript usage, including how to access command line arguments from the script, see the osascript(1) man page. [2468788]

There is a command-line tool to display compiled scripts as text, /usr/bin/osadecompile. [4501123]

osascript(1) and osacompile(1) now correctly handle text scripts encoded as UTF-8, in addition to UTF-16 and the primary encoding. If a script is neither UTF-8 nor UTF-16, it is presumed to be encoded using the primary encoding.

Other Enhancements

Bug Fixes

Developer Notes