-- testAS.applescript

-- TextEdit+

-- When user clicks Update button get statistics information and then set contents of text fields

on clicked theObject

    set theWindow to window of theObject

    try

        populateTextFields(theWindow)

    on error errMsg

        log errMsg

    end try

end clicked

-- When Document Properties window is open, clear text fields, get statistics information and then set contents of text fields

on opened theObject

    set theWindow to theObject

    tell theWindow

        set contents of text field "CharacterCount" of box "Statistics" to ""

        set contents of text field "WordCount" of box "Statistics" to ""

        set contents of text field "ParagraphCount" of box "Statistics" to ""

    end tell

    populateTextFields(theWindow)

end opened

-- Ask TextEdit for document text information using AppleScript

on DocCount()

    tell application "TextEdit"

        activate

        set theData to text of the front document

        set charCount to length of theData

        set wordCount to number of words in theData

        set paragraphCount to number of paragraphs in theData

    end tell

    set DocCountInfoRecord to {charCount:charCount, wordCount:wordCount, paragraphCount:paragraphCount}

    return DocCountInfoRecord

end DocCount

--Set contents of text fields with statistics information

on populateTextFields(theWindow)

    try

        tell progress indicator "DocCount" of box "Statistics" of theWindow to start

        set DocCountInfoRecord to DocCount()

        tell theWindow

            set contents of text field "CharacterCount" of box "Statistics" to charCount of DocCountInfoRecord

            set contents of text field "WordCount" of box "Statistics" to wordCount of DocCountInfoRecord

            set contents of text field "ParagraphCount" of box "Statistics" to paragraphCount of DocCountInfoRecord

            tell progress indicator "DocCount" of box "Statistics" to stop

        end tell

    on error errMsg

        log errMsg

    end try

end populateTextFields

(*

Disclaimer: IMPORTANT:  This Apple software is supplied to you by Apple

Computer, Inc. ("Apple") in consideration of your agreement to the

following terms, and your use, installation, modification or

redistribution of this Apple software constitutes acceptance of these

terms.  If you do not agree with these terms, please do not use,

install, modify or redistribute this Apple software.

In consideration of your agreement to abide by the following terms, and

subject to these terms, Apple grants you a personal, non-exclusive

license, under Apple's copyrights in this original Apple software (the

"Apple Software"), to use, reproduce, modify and redistribute the Apple

Software, with or without modifications, in source and/or binary forms;

provided that if you redistribute the Apple Software in its entirety and

without modifications, you must retain this notice and the following

text and disclaimers in all such redistributions of the Apple Software. 

Neither the name, trademarks, service marks or logos of Apple Computer,

Inc. may be used to endorse or promote products derived from the Apple

Software without specific prior written permission from Apple.  Except

as expressly stated in this notice, no other rights or licenses, express

or implied, are granted by Apple herein, including but not limited to

any patent rights that may be infringed by your derivative works or by

other works in which the Apple Software may be incorporated.

The Apple Software is provided by Apple on an "AS IS" basis.  APPLE

MAKES NO WARRANTIES, EXPRESS OR IMPLIED, INCLUDING WITHOUT LIMITATION

THE IMPLIED WARRANTIES OF NON-INFRINGEMENT, MERCHANTABILITY AND FITNESS

FOR A PARTICULAR PURPOSE, REGARDING THE APPLE SOFTWARE OR ITS USE AND

OPERATION ALONE OR IN COMBINATION WITH YOUR PRODUCTS.

IN NO EVENT SHALL APPLE BE LIABLE FOR ANY SPECIAL, INDIRECT, INCIDENTAL

OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF

SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS

INTERRUPTION) ARISING IN ANY WAY OUT OF THE USE, REPRODUCTION,

MODIFICATION AND/OR DISTRIBUTION OF THE APPLE SOFTWARE, HOWEVER CAUSED

AND WHETHER UNDER THEORY OF CONTRACT, TORT (INCLUDING NEGLIGENCE),

STRICT LIABILITY OR OTHERWISE, EVEN IF APPLE HAS BEEN ADVISED OF THE

POSSIBILITY OF SUCH DAMAGE.

Copyright © 2006 Apple Computer, Inc., All Rights Reserved

*)